Stationeers [Europa] - Compact Oxygen Collection Build Guide

Stationeers 2025 Version 0.2.5499.24517

Here is my favourite Oxygen collector setup for Europa. It’s compact, and can provide both gaseous and liquid O2. (You will want to use caution if you are going to collect the liquid though… use the Analyzer to detect 100% liquid O2 before pumping.) The gas side requires no filtering as it naturally rejects anything but pure Oxygen.

I like to use this super cold gas to mix with my volatiles/H2 and run my Gas Fuel Generators on it, it gives a nice performance boost over warm fuel mixtures.

[BOM] What you will need

• 1 X Iron/Steel Frame

• 1 X Iron/Steel Sheet

• 2 X Plastic Sheet - For Powered Vent Build

• 16 X Kit (Insulated Liquid Pipe)

• 5 X Kit (Insulated Pipe Utility Liquid)

• 3 X Kit (Liquid Drain)

• 1 X Kit (Liquid Pipe Analyzer)

• 1 X Kit (Pipe Analyzer)

• 26 X Kit (Insulated Pipe)

• 11 X Kit (Insulated Pipe Utility Gas)

• 1 X Kit (Pipe Meter)

• 5 X Kit (Pipe Valve)

• 1 X Kit (Tank Insulated)

• 1 X Kit (Turbo Volume Pump - Gas)

• 2 X Kit (Pipe) - For Powered Vent Build

• 1 X Kit (Powered Vent)

• 47 X Cable Coil

• 1 X Kit (IC Housing)

• 1 X Integrated Circuit (IC10)

• 1 X Kit (Transformer Small)

Stage 1

Place the Iron/Steel Frame and layout your liquid pipes, drains, and Analyzer as shown. You will need to weld the frame in order to place the two drains.

Stage 2

Add the 5 condensation valves (From the Kit (Pipe Valve) as shown. Make sure the arrow points down.

Stage 3

Place 3 In-line Tank Gas (Insulated) [buit from the Kit (Insulated Pipe Utility Gas)] at the back, near the liquid drains.

Place an addional 5 In-line Tank Small Gas (Insulated) as shown

Place the connecting insulated pipes as shown below, as well as the gas analyzer with the cable connection pointing up.

Stage 4

On top of the frame, add your insulated tank, insulated piping with the remaining liquid drain, and the pipe meter. This should connect to the Turbo Volume Pump - be sure to orient the electrical connection to the left.

Stage 5

Re-Weld the frame so you can place the Transformer, IC Housing and Powered Vent. Once placed Un-Weld it and connect the cabling as shown.

Stage 6

Program the IC10 Chip with the following program. Available on the Steam Workshop.

alias StorageTank d0
alias VolumePump d1
alias PoweredVent d2
alias GasAnalyzer d3
alias LiquidAnalyzer d4
alias MaxLiquid r15
alias VolPumpSpeed r14
define LiquidOutlets 1687692899
define MaxPressure 20000 #kPa - Change to the max pressure you want to see in your piping
define TankMaxPressure 35000 #kPa - System will run if tank is under this pressure
#Initialize on Startup
jal SET.MAXLIQUID
jal MODE.OFF
STAGE.MAIN:
  #check to see if the tank pressure is low enought to start making gas
  l r0 StorageTank Pressure
  ble r0 TankMaxPressure STAGE.MAKEGAS
  yield
j STAGE.MAIN
STAGE.MAKEGAS:
  #stuff the pipes full of air until they are full or the liquid side is full
  jal MODE.CHARGE
  l r0 GasAnalyzer Pressure
  l r1 LiquidAnalyzer VolumeOfLiquid
  sge r2 r0 MaxPressure
  sge r3 r1 MaxLiquid
  or r4 r2 r3
  bgtz r4 STAGE.GASIFY
  yield
j STAGE.MAKEGAS
STAGE.GASIFY:
  #wait for all liquid/vapour to leave the gas pipe leaving only O2 Gas
  jal MODE.IDLE
  l r0 GasAnalyzer RatioOxygen
  beqal r0 1.0 SLEEP
  beq r0 1.0 STAGE.PUMPOUT
  yield
j STAGE.GASIFY
STAGE.PUMPOUT:
  #pump all the gas into the tank
  jal MODE.TRANSFER
  jal SOFTSTART
  l r0 GasAnalyzer Pressure
  l r1 StorageTank Pressure
  slez r2 r0
  sge r3 r1 MaxPressure
  or r4 r2 r3
  bgtzal r4 MODE.OFF
  bgtz r4 STAGE.MAIN
  yield
j STAGE.PUMPOUT
MODE.OFF:
  s PoweredVent Mode 1
  s PoweredVent On 0
  s VolumePump Mode 0
  s VolumePump Setting 0.0
  move VolPumpSpeed 0.0
  s VolumePump On 0
  s GasAnalyzer On 0
  s LiquidAnalyzer On 0
  sb LiquidOutlets On 0
j ra
MODE.CHARGE:
  s PoweredVent On 1
  s VolumePump On 0
  s GasAnalyzer On 1
  s LiquidAnalyzer On 1
  sb LiquidOutlets On 1
j ra
MODE.IDLE:
  s PoweredVent On 0
  s VolumePump On 0
  s GasAnalyzer On 1
  s LiquidAnalyzer On 1
  sb LiquidOutlets On 1
j ra
MODE.TRANSFER:
  s PoweredVent On 0
  s VolumePump On 1
  s GasAnalyzer On 1
  s LiquidAnalyzer On 1
  sb LiquidOutlets On 1
j ra
SET.MAXLIQUID:
  # Sets the system liquid volume capability, with a safety margin
  s LiquidAnalyzer On 1
  yield
  l r0 LiquidAnalyzer Volume
  mul r1 r0 0.7
  move MaxLiquid r1
  s LiquidAnalyzer On 0
j ra
SLEEP:
  #waits additional 30 seconds to ensure pipes clear
  sleep 30
j ra
SOFTSTART:
  #idles up the volume pump to reduce stress on tank/pipes
  brge VolPumpSpeed 100.0 2
  add VolPumpSpeed VolPumpSpeed 1.0
  s VolumePump Setting VolPumpSpeed
j ra

You may want to play with the MaxPressure variable so It works for you. I have found that 20MPa is just about right as the rate of collection starts to slow a bit after anything higher